1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//build/config/features.gni")
import("//mojo/public/tools/bindings/mojom.gni")
component("battery") {
output_name = "device_battery"
sources = [
"battery_export.h",
"battery_monitor_impl.cc",
"battery_monitor_impl.h",
"battery_status_manager_android.cc",
"battery_status_manager_android.h",
"battery_status_manager_chromeos.cc",
"battery_status_manager_default.cc",
"battery_status_manager_linux.cc",
"battery_status_manager_linux.h",
"battery_status_manager_mac.cc",
"battery_status_manager_win.cc",
"battery_status_manager_win.h",
"battery_status_service.cc",
"battery_status_service.h",
]
defines = [
"DEVICE_BATTERY_IMPLEMENTATION",
]
deps = [
":mojo_bindings",
"//base",
"//base/third_party/dynamic_annotations",
"//mojo/environment:chromium",
"//mojo/public/cpp/bindings",
"//mojo/edk/system",
]
if (is_android) {
deps += [
"//device/battery/android:battery_jni_headers",
]
sources += [
"android/battery_jni_registrar.h",
"android/battery_jni_registrar.cc",
]
sources -= [
"battery_status_manager_default.cc",
]
}
if (is_chromeos) {
configs += [
"//build/config/linux:dbus",
]
deps += [
"//chromeos:power_manager_proto",
]
sources -= [
"battery_status_manager_default.cc",
"battery_status_manager_linux.cc",
]
}
if (is_desktop_linux) {
if (use_dbus) {
configs += [
"//build/config/linux:dbus",
]
deps += [
"//dbus"
]
sources -= [
"battery_status_manager_default.cc",
]
} else {
sources -= [
"battery_status_manager_linux.cc",
]
}
}
if (is_mac) {
sources -= [
"battery_status_manager_default.cc",
]
}
if (is_win) {
sources -= [
"battery_status_manager_default.cc",
]
}
}
mojom("mojo_bindings") {
sources = [
"battery_monitor.mojom",
"battery_status.mojom",
]
}
|
