1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
|
@/*****************************************************************************
@*
@* Copyright (C) 2012 Ittiam Systems Pvt Ltd, Bangalore
@*
@* Licensed under the Apache License, Version 2.0 (the "License");
@* you may not use this file except in compliance with the License.
@* You may obtain a copy of the License at:
@*
@* http://www.apache.org/licenses/LICENSE-2.0
@*
@* Unless required by applicable law or agreed to in writing, software
@* distributed under the License is distributed on an "AS IS" BASIS,
@* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
@* See the License for the specific language governing permissions and
@* limitations under the License.
@*
@*****************************************************************************/
@/**
@*******************************************************************************
@* @file
@* ihevc_intra_pred_filters_planar.s
@*
@* @brief
@* contains function definitions for inter prediction interpolation.
@* functions are coded using neon intrinsics and can be compiled using
@* rvct
@*
@* @author
@* akshaya mukund
@*
@* @par list of functions:
@*
@*
@* @remarks
@* none
@*
@*******************************************************************************
@*/
@/**
@*******************************************************************************
@*
@* @brief
@* luma intraprediction filter for planar input
@*
@* @par description:
@*
@* @param[in] pu1_ref
@* uword8 pointer to the source
@*
@* @param[out] pu1_dst
@* uword8 pointer to the destination
@*
@* @param[in] src_strd
@* integer source stride
@*
@* @param[in] dst_strd
@* integer destination stride
@*
@* @param[in] pi1_coeff
@* word8 pointer to the planar coefficients
@*
@* @param[in] nt
@* size of tranform block
@*
@* @param[in] mode
@* type of filtering
@*
@* @returns
@*
@* @remarks
@* none
@*
@*******************************************************************************
@*/
@void ihevc_intra_pred_luma_planar(uword8* pu1_ref,
@ word32 src_strd,
@ uword8* pu1_dst,
@ word32 dst_strd,
@ word32 nt,
@ word32 mode,
@ word32 pi1_coeff)
@**************variables vs registers*****************************************
@r0 => *pu1_ref
@r1 => src_strd
@r2 => *pu1_dst
@r3 => dst_strd
@stack contents from #104
@ nt
@ mode
@ pi1_coeff
.equ nt_offset, 104
.text
.align 4
.globl ihevc_intra_pred_chroma_planar_a9q
.extern gau1_ihevc_planar_factor
gau1_ihevc_planar_factor_addr:
.long gau1_ihevc_planar_factor - ulbl1 - 8
.type ihevc_intra_pred_chroma_planar_a9q, %function
ihevc_intra_pred_chroma_planar_a9q:
stmfd sp!, {r4-r12, r14} @stack stores the values of the arguments
vpush {d8 - d15}
ldr r4,[sp,#nt_offset] @loads nt
ldr r11, gau1_ihevc_planar_factor_addr @loads table of coeffs
ulbl1:
add r11,r11,pc
clz r5, r4
rsb r5, r5, #32
vdup.16 q7, r5
vneg.s16 q7, q7 @shr value (so vneg)
vdup.8 d2, r4 @nt
vdup.s16 q8, r4 @nt
sub r6, r4, #1 @nt-1
add r6, r0,r6,lsl #1 @2*(nt-1)
ldr r7, [r6]
vdup.s16 d0, r7 @src[nt-1]
add r6, r4, r4,lsl #1 @3nt
add r6, r6, #1 @3nt + 1
lsl r6,r6,#1 @2*(3nt + 1)
add r6, r6, r0
ldr r7, [r6]
vdup.s16 d1, r7 @src[3nt+1]
add r6, r4, r4 @2nt
add r14, r6, #1 @2nt+1
lsl r14,#1 @2*(2nt+1)
sub r6, r6, #1 @2nt-1
lsl r6,#1 @2*(2nt-1)
add r6, r6, r0 @&src[2nt-1]
add r14, r14, r0 @&src[2nt+1]
mov r8, #1 @row+1 (row is first 0)
sub r9, r4, r8 @nt-1-row (row is first 0)
vdup.s8 d5, r8 @row + 1
vdup.s8 d6, r9 @nt - 1 - row
vmov d7, d5 @mov #1 to d7 to used for inc for row+1 and dec for nt-1-row
add r12, r11, #1 @coeffs (to be reloaded after every row)
mov r1, r4 @nt (row counter) (dec after every row)
mov r5, r2 @dst (to be reloaded after every row and inc by dst_strd)
mov r10, #8 @increment for the coeffs
mov r0, r14 @&src[2nt+1] (to be reloaded after every row)
cmp r4, #4
beq tf_sz_4
mov r10,r6
tf_sz_8_16:
vld1.s8 {d10,d11}, [r14]! @load src[2nt+1+col]
vld1.s8 d8, [r12]!
vmov d9,d8
vzip.8 d8,d9
vsub.s8 d30, d2, d8 @[nt-1-col]
vsub.s8 d31, d2, d9
loop_sz_8_16:
ldr r7, [r6], #-2 @src[2nt-1-row] (dec to take into account row)
vmull.u8 q6, d5, d0 @(row+1) * src[nt-1]
ldr r11, [r6], #-2 @src[2nt-1-row] (dec to take into account row)
vmlal.u8 q6, d6, d10 @(nt-1-row) * src[2nt+1+col]
vdup.s16 d4, r7 @src[2nt-1-row]
vmlal.u8 q6, d8, d1 @(col+1) * src[3nt+1]
vdup.s16 d3, r11 @src[2nt-1-row]
vmlal.u8 q6, d30, d4 @(nt-1-col) * src[2nt-1-row]
vmull.u8 q14,d5,d0
ldr r7, [r6], #-2 @src[2nt-1-row] (dec to take into account row)
vmlal.u8 q14,d6,d11
vadd.s8 d18, d5, d7 @row++ [(row+1)++]c
vmlal.u8 q14,d31,d4
vsub.s8 d19, d6, d7 @[nt-1-row]--
vmlal.u8 q14,d9,d1
vdup.s16 d4, r7 @src[2nt-1-row]
vmull.u8 q13, d18, d0 @(row+1) * src[nt-1]
vadd.i16 q6, q6, q8 @add (nt)
vmlal.u8 q13, d19, d10 @(nt-1-row) * src[2nt+1+col]
vshl.s16 q6, q6, q7 @shr
vmlal.u8 q13, d8, d1 @(col+1) * src[3nt+1]
vadd.i16 q14,q14,q8
vmlal.u8 q13, d30, d3 @(nt-1-col) * src[2nt-1-row]
vshl.s16 q14,q14,q7
vmull.u8 q12,d18,d0
vadd.s8 d5, d18, d7 @row++ [(row+1)++]
vmlal.u8 q12,d19,d11
vsub.s8 d6, d19, d7 @[nt-1-row]--
vmlal.u8 q12,d9,d1
vmovn.i16 d12, q6
vmlal.u8 q12,d31,d3
vmovn.i16 d13,q14
vadd.i16 q13, q13, q8 @add (nt)
vmull.u8 q11, d5, d0 @(row+1) * src[nt-1]
vshl.s16 q13, q13, q7 @shr
vmlal.u8 q11, d6, d10 @(nt-1-row) * src[2nt+1+col]
vst1.s32 {d12,d13}, [r2], r3
vmlal.u8 q11, d8, d1 @(col+1) * src[3nt+1]
vadd.i16 q12,q12,q8
vmlal.u8 q11, d30, d4 @(nt-1-col) * src[2nt-1-row]
vshl.s16 q12,q12,q7
vmull.u8 q10,d5,d0
vadd.s8 d18, d5, d7 @row++ [(row+1)++]c
vmlal.u8 q10,d6,d11
vsub.s8 d19, d6, d7 @[nt-1-row]--
vmlal.u8 q10,d31,d4
ldr r11, [r6], #-2 @src[2nt-1-row] (dec to take into account row)
vmlal.u8 q10,d9,d1
vdup.s16 d3, r11 @src[2nt-1-row]
vadd.i16 q11, q11, q8 @add (nt)
vmull.u8 q6, d18, d0 @(row+1) * src[nt-1]
vmovn.i16 d26, q13
vmlal.u8 q6, d19, d10 @(nt-1-row) * src[2nt+1+col]
vmovn.i16 d27,q12
vmlal.u8 q6, d8, d1 @(col+1) * src[3nt+1]
vshl.s16 q11, q11, q7 @shr
vmlal.u8 q6, d30, d3 @(nt-1-col) * src[2nt-1-row]
vadd.i16 q10,q10,q8
vmull.u8 q14,d18,d0
vst1.s32 {d26,d27}, [r2], r3
vmlal.u8 q14,d19,d11
vadd.s8 d5, d18, d7 @row++ [(row+1)++]
vsub.s8 d6, d19, d7 @[nt-1-row]--
vmlal.u8 q14,d9,d1
vmlal.u8 q14,d31,d3
vshl.s16 q10,q10,q7
vadd.i16 q6, q6 ,q8 @add (nt)
vmovn.i16 d22, q11
vadd.i16 q14,q14,q8
vmovn.i16 d23,q10
vshl.s16 q6, q6, q7 @shr
vst1.s32 {d22,d23}, [r2], r3
vshl.s16 q14,q14,q7
vmovn.i16 d20, q6
vmovn.i16 d21,q14
vst1.s32 {d20,d21}, [r2], r3
subs r1, r1, #4
bne loop_sz_8_16
cmp r4,#16
bne end_loop
sub r4,#16
vdup.s8 d5, r8 @row + 1
vdup.s8 d6, r9 @nt - 1 - row
vmov d7, d5 @mov #1 to d7 to used for inc for row+1 and dec for nt-1-row
mov r6,r10
mov r1,#16
sub r2,r2,r3,lsl #4
add r2,r2,#16
vld1.s8 {d10,d11}, [r14]! @load src[2nt+1+col]
vld1.s8 d8, [r12]!
vmov d9,d8
vzip.8 d8,d9
vsub.s8 d30, d2, d8 @[nt-1-col]
vsub.s8 d31, d2, d9
beq loop_sz_8_16
tf_sz_4:
vld1.s8 d10, [r14] @load src[2nt+1+col]
vld1.s8 d8, [r12], r10 @load 8 coeffs [col+1]
vmov d9,d8
vzip.8 d8,d9
loop_sz_4:
@mov r10, #4 @reduce inc to #4 for 4x4
ldr r7, [r6], #-2 @src[2nt-1-row] (dec to take into account row)
vdup.s16 d4, r7 @src[2nt-1-row]
vsub.s8 d9, d2, d8 @[nt-1-col]
vmull.u8 q6, d5, d0 @(row+1) * src[nt-1]
vmlal.u8 q6, d6, d10 @(nt-1-row) * src[2nt+1+col]
vmlal.u8 q6, d8, d1 @(col+1) * src[3nt+1]
vmlal.u8 q6, d9, d4 @(nt-1-col) * src[2nt-1-row]
@ vadd.i16 q6, q6, q8 @add (nt)
@ vshl.s16 q6, q6, q7 @shr
@ vmovn.i16 d12, q6
vrshrn.s16 d12,q6,#3
vst1.s32 {d12}, [r2], r3
vadd.s8 d5, d5, d7 @row++ [(row+1)++]
vsub.s8 d6, d6, d7 @[nt-1-row]--
subs r1, r1, #1
bne loop_sz_4
end_loop:
vpop {d8 - d15}
ldmfd sp!,{r4-r12,r15} @reload the registers from sp
|