# Copyright 2021 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")
import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_third_party/mbedtls/mbedtls.gni")
import("$dir_pw_tls_client/configs.gni")
import("$dir_pw_unit_test/test.gni")

config("public_includes") {
  include_dirs = [ "public" ]
}

config("overrides") {
  include_dirs = [ "public_overrides" ]
}

pw_source_set("pw_tls_client_mbedtls") {
  public_configs = [
    ":public_includes",
    ":overrides",
  ]
  public = [
    "public/pw_tls_client_mbedtls/backend_types.h",
    "public_overrides/pw_tls_client_backends/backend_types.h",
  ]
  sources = [ "tls_client_mbedtls.cc" ]
  public_deps = [
    "$dir_pigweed/pw_tls_client:pw_tls_client.facade",
    "$dir_pw_assert",
    "$dir_pw_log",
    "$dir_pw_stream",
    "$dir_pw_third_party/mbedtls",
    "$dir_pw_tls_client:tls_entropy",
  ]
}

pw_test("tls_client_mbedtls_test") {
  enable_if =
      pw_tls_client_ENTROPY_BACKEND != "" && dir_pw_third_party_mbedtls != ""
  deps = [ ":pw_tls_client_mbedtls" ]
  sources = [ "tls_client_mbedtls_test.cc" ]
}

pw_test_group("tests") {
  tests = [ ":tls_client_mbedtls_test" ]
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}