targets/docs/BUILD.gn


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pigweed/targets/stm32f429i-disc1/target_toolchains.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_protobuf_compiler/proto.gni")
import("$dir_pw_third_party/nanopb/nanopb.gni")
import("$dir_pw_toolchain/arm_gcc/toolchains.gni")
import("$dir_pw_toolchain/generate_toolchain.gni")

# Toolchain for generating upstream Pigweed documentation.
generate_toolchain("docs") {
  # Use the stm32f429i-disc1 toolchain for pw_size_report targets.
  _base_toolchain = pw_target_toolchain_stm32f429i_disc1.size_optimized
  forward_variables_from(_base_toolchain,
                         "*",
                         [
                           "defaults",
                           "name",
                         ])
  defaults = {
    forward_variables_from(_base_toolchain.defaults, "*")

    _has_nanopb_rpc = pw_protobuf_GENERATORS + [ "nanopb_rpc" ] -
                      [ "nanopb_rpc" ] != pw_protobuf_GENERATORS
    if (dir_pw_third_party_nanopb != "" && !_has_nanopb_rpc) {
      pw_protobuf_GENERATORS += [ "nanopb_rpc" ]
    }

    # This is the docs target.
    pw_docgen_BUILD_DOCS = true
  }
}

pw_doc_group("target_docs") {
  sources = [ "target_docs.rst" ]
}