blob: ef32f4d795ff3feb13f60c14077836c34d780945 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
|
/*
* cmsdk_cm0_user_flash.ld
* Linker script for user application executing from external flash
*
* Copyright (C) Atmosic 2017-2021
*/
INCLUDE "lib-nosys.ld"
INCLUDE "memory.ld"
ENTRY(_user_entry)
SECTIONS
{
.text :
{
__text_start__ = .;
KEEP(*(.user_entry))
*(.text*)
KEEP(*(.KEEP.text*))
KEEP(*(.init))
KEEP(*(.fini))
/* .ctors */
*crtbegin.o(.ctors)
*crtbegin?.o(.ctors)
*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors)
*(SORT(.ctors.*))
*(.ctors)
/* .dtors */
*crtbegin.o(.dtors)
*crtbegin?.o(.dtors)
*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors)
*(SORT(.dtors.*))
*(.dtors)
*(.rodata*)
KEEP(*(.eh_frame*))
} > UFLASH
. = ALIGN(4);
__atm_module_start = .;
.ATM.module :
{
KEEP(*(SORT(.atm_module.*)))
} > UFLASH
__atm_module_end = .;
. = ALIGN(4);
__at_cmd_start = .;
.ATCOMMAND :
{
KEEP(*(SORT(.at_cmd.*)))
} > UFLASH
__at_cmd_end = .;
.ARM.extab :
{
*(.ARM.extab* .gnu.linkonce.armextab.*)
} > UFLASH
__exidx_start = .;
.ARM.exidx :
{
*(.ARM.exidx* .gnu.linkonce.armexidx.*)
} > UFLASH
__exidx_end = .;
. = ALIGN(4);
__etext = .;
.data : AT (__etext)
{
__data_start__ = .;
*(vtable)
*(.data*)
. = ALIGN(4);
/* preinit data */
PROVIDE_HIDDEN (__preinit_array_start = .);
KEEP(*(.preinit_array))
PROVIDE_HIDDEN (__preinit_array_end = .);
. = ALIGN(4);
/* init data */
PROVIDE_HIDDEN (__init_array_start = .);
KEEP(*(SORT(.init_array.*)))
KEEP(*(.init_array))
PROVIDE_HIDDEN (__init_array_end = .);
. = ALIGN(4);
/* finit data */
PROVIDE_HIDDEN (__fini_array_start = .);
KEEP(*(SORT(.fini_array.*)))
KEEP(*(.fini_array))
PROVIDE_HIDDEN (__fini_array_end = .);
KEEP(*(.jcr*))
. = ALIGN(4);
/* All data end */
__data_end__ = .;
} > URAM
/* Check if UFLASH overflowed */
ASSERT((__etext - ORIGIN(UFLASH)) + (__data_end__ - __data_start__) < LENGTH(UFLASH), "section .data does not fit in region UFLASH")
__NVDS_Flash = ORIGIN(NVDS);
__NVDS_FlashEnd = ORIGIN(NVDS) + LENGTH(NVDS);
__User_Flash = ORIGIN(USER);
__User_FlashEnd = ORIGIN(USER) + LENGTH(USER);
.bss :
{
. = ALIGN(4);
__bss_start__ = .;
*(.bss*)
*(COMMON)
. = ALIGN(4);
__bss_end__ = .;
} > URAM
.uninit (NOLOAD) :
{
. = ALIGN(4);
*(.uninit*)
. = ALIGN(4);
} > URAM
}
|
