Merge "Merge remote-tracking branch 'aosp/upstream-main' into aosp" am: 7dc4c9792d am: 047d79edce am: 4f9c193349 am: c66e2fa10daml_wif_341711020aml_wif_341610000aml_wif_341510000aml_wif_341410080aml_wif_341310010aml_wif_341110010aml_wif_341011010aml_wif_340913010aml_uwb_341710010aml_uwb_341513070aml_uwb_341511050aml_uwb_341310300aml_uwb_341310030aml_uwb_341111010aml_uwb_341011000aml_tet_341712060aml_tet_341610020aml_tet_341511010aml_tet_341411060aml_tet_341310230aml_tet_341112070aml_tet_341010040aml_tet_340913030aml_swc_341711000aml_swc_341619000aml_swc_341513600aml_swc_341312300aml_swc_341312020aml_swc_341111000aml_swc_341011020aml_swc_340922010aml_sta_341710000aml_sta_341615000aml_sta_341511040aml_sta_341410000aml_sta_341311010aml_sta_341114000aml_sta_341111000aml_sta_341010020aml_sta_340912000aml_sta_340911000aml_sdk_341710000aml_sdk_341510000aml_sdk_341410000aml_sdk_341110080aml_sdk_341110000aml_sdk_341010000aml_sdk_340912010aml_sch_341510000aml_res_341510000aml_res_341410010aml_res_341311030aml_res_341110000aml_res_340912000aml_per_341711000aml_per_341614000aml_per_341510010aml_per_341410020aml_per_341311000aml_per_341110020aml_per_341110010aml_per_341011100aml_per_341011020aml_per_340916010aml_odp_341717000aml_odp_341610000aml_neu_341510000aml_neu_341010080aml_neu_341010000aml_net_341710020aml_net_341610030aml_net_341510050aml_net_341510000aml_net_341411030aml_net_341311010aml_net_341310020aml_net_341111030aml_net_341014000aml_net_340913000aml_mpr_341713020aml_mpr_341614010aml_mpr_341511070aml_mpr_341411070aml_mpr_341313030aml_mpr_341111030aml_mpr_341111020aml_mpr_341015090aml_mpr_341015030aml_mpr_340919000aml_med_341711000aml_med_341619000aml_med_341513600aml_med_341312300aml_med_341312020aml_med_341111000aml_med_341011000aml_med_340922010aml_ips_341611000aml_ips_341510000aml_ips_340914280aml_ips_340914200aml_ips_340914000aml_ext_341716000aml_ext_341620040aml_ext_341518010aml_ext_341414010aml_ext_341317010aml_ext_341131030aml_ext_341027030aml_doc_341713000aml_doc_341610010aml_doc_341510050aml_doc_341312010aml_doc_341112000aml_doc_341012000aml_doc_340916000aml_con_341614000aml_con_341511080aml_con_341410300aml_con_341310090aml_con_341110000aml_cbr_341710000aml_cbr_341610000aml_cbr_341510010aml_cbr_341410010aml_cbr_341311010aml_cbr_341110000aml_cbr_341011000aml_cbr_340914000aml_ase_341510000aml_ase_341410000aml_ase_341310010aml_ase_341113000aml_ase_340913000aml_art_341711000aml_art_341615020aml_art_341514450aml_art_341514410aml_art_341411300aml_art_341311100aml_art_341110110aml_art_341110060aml_art_341010050aml_art_340915060aml_ads_341720000aml_ads_341615050aml_ads_341517040aml_ads_341413000aml_ads_341316030aml_ads_341131050aml_ads_341027030aml_ads_340915050aml_adb_341520010aml_adb_341517070aml_adb_340912530aml_adb_340912350aml_adb_340912200aml_adb_340912000android14-mainline-wifi-releaseandroid14-mainline-uwb-releaseandroid14-mainline-tethering-releaseandroid14-mainline-sdkext-releaseandroid14-mainline-resolv-releaseandroid14-mainline-permission-releaseandroid14-mainline-os-statsd-releaseandroid14-mainline-networking-releaseandroid14-mainline-mediaprovider-releaseandroid14-mainline-media-swcodec-releaseandroid14-mainline-media-releaseandroid14-mainline-extservices-releaseandroid14-mainline-conscrypt-releaseandroid14-mainline-cellbroadcast-releaseandroid14-mainline-art-releaseandroid14-mainline-appsearch-releaseandroid14-mainline-adservices-releaseandroid14-mainline-adbd-release

Original change: https://android-review.googlesource.com/c/platform/external/bazelbuild-kotlin-rules/+/2484976

Change-Id: I9ff3e9a9031fa708d074cdfeada3cd23ea9c681c
Signed-off-by: Automerger Merge Worker <android-build-automerger-merge-worker@system.gserviceaccount.com>

1 files changed, 122 insertions, 0 deletions

diff --git a/kotlin/jvm/internal_do_not_use/traverse_exports/traverse_exports.bzl b/kotlin/jvm/internal_do_not_use/traverse_exports/traverse_exports.bzl
new file mode 100644
index 0000000..f0f9e6a
--- /dev/null
+++ b/kotlin/jvm/internal_do_not_use/traverse_exports/traverse_exports.bzl
@@ -0,0 +1,122 @@
+# Copyright 2022 Google LLC. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the License);
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Combined aspect for all rules_kotlin behaviours that need to traverse exports."""
+
+load(":compiler_plugin.bzl", "kt_compiler_plugin_visitor")
+load(":direct_jdeps.bzl", "kt_direct_jdeps_visitor")
+load(":forbidden_deps.bzl", "kt_forbidden_deps_visitor")
+load(":friend_jars.bzl", "kt_friend_jars_visitor", "kt_friend_labels_visitor")
+load(":java_plugin.bzl", "java_plugin_visitor")
+load("//:visibility.bzl", "RULES_KOTLIN")
+
+# java_xxx_proto_library don't populate java_outputs but we can get them through
+# required_aspect_providers from their proto_library deps.
+_DEPS_AS_EXPORTS_RULES = [
+    "java_proto_library",
+    "java_lite_proto_library",
+    "java_mutable_proto_library",
+]
+
+_NO_SRCS_DEPS_AS_EXPORTS_RULES = [
+    "proto_library",
+]
+
+# visitor = struct[T](
+#     name = string,
+#     visit_target = function(Target, ctx.rule): list[T],
+#     filter_edge = None|(function(src: ?, dest: Target): bool),
+#     process_unvisited_target = None|(function(Target): list[T]),
+#     finish_expansion = None|(function(depset[T]): depset[T]),
+# )
+_VISITORS = [
+    kt_forbidden_deps_visitor,
+    kt_direct_jdeps_visitor,
+    kt_compiler_plugin_visitor,
+    kt_friend_jars_visitor,
+    kt_friend_labels_visitor,
+    java_plugin_visitor,
+]
+
+_KtTraverseExportsInfo = provider(
+    doc = "depsets for transitive info about exports",
+    fields = {
+        v.name: ("depset[%s]" % v.name)
+        for v in _VISITORS
+    },
+)
+
+_EMPTY_KT_TRAVERSE_EXPORTS_INFO = _KtTraverseExportsInfo(**{
+    v.name: depset()
+    for v in _VISITORS
+})
+
+def _aspect_impl(target, ctx):
+    if not (JavaInfo in target):
+        # Ignore non-JVM targets. This also chops-up the
+        # traversal domain at these targets.
+        # TODO: Support non-JVM targets for KMP
+        return _EMPTY_KT_TRAVERSE_EXPORTS_INFO
+
+    exports = []
+    exports.extend(getattr(ctx.rule.attr, "exports", []))  # exports list is frozen
+    if ctx.rule.kind in _DEPS_AS_EXPORTS_RULES:
+        exports.extend(ctx.rule.attr.deps)
+    elif ctx.rule.kind in _NO_SRCS_DEPS_AS_EXPORTS_RULES and not ctx.rule.attr.srcs:
+        exports.extend(ctx.rule.attr.deps)
+
+    return _KtTraverseExportsInfo(**{
+        v.name: depset(
+            direct = v.visit_target(target, ctx.rule),
+            transitive = [
+                getattr(e[_KtTraverseExportsInfo], v.name)
+                for e in exports
+                if (not v.filter_edge or v.filter_edge(target, e))
+            ],
+        )
+        for v in _VISITORS
+    })
+
+_aspect = aspect(
+    implementation = _aspect_impl,
+    provides = [_KtTraverseExportsInfo],
+    # Transitively check exports, since they are effectively directly depended on.
+    # "deps" needed for rules that treat deps as exports (usually absent srcs).
+    attr_aspects = ["exports", "deps"],
+    required_aspect_providers = [JavaInfo],  # to get at JavaXxxProtoAspects' JavaInfos
+)
+
+def _create_visitor_expand(visitor):
+    def _visitor_expand(targets, root = None):
+        direct = []
+        transitive = []
+        for t in targets:
+            if (not visitor.filter_edge or visitor.filter_edge(root, t)):
+                if _KtTraverseExportsInfo in t:
+                    transitive.append(getattr(t[_KtTraverseExportsInfo], visitor.name))
+                elif visitor.process_unvisited_target:
+                    direct.extend(visitor.process_unvisited_target(t))
+
+        expanded_set = depset(direct = direct, transitive = transitive)
+        return visitor.finish_expansion(expanded_set) if visitor.finish_expansion else expanded_set
+
+    return _visitor_expand
+
+kt_traverse_exports = struct(
+    aspect = _aspect,
+    **{
+        "expand_" + v.name: _create_visitor_expand(v)
+        for v in _VISITORS
+    }
+)