configure: print feature settings overview

elfutils can be configured in various ways. But we expect certain
settings for the features that we explicitly support. Print an
overview of all settings, plus their recommended setting, at the
end of the configure run.

=====================================================================
        elfutils: 0.161 (eu_version: 161)
=====================================================================

    Prefix                             : /opt/local/install/elfutils
    Program prefix ("eu-" recommended) : eu-
    Source code location               : /home/mark/src/elfutils
    Maintainer mode                    : yes
    libebl modules subdirectory        : elfutils
    build arch                         : x86_64-unknown-linux-gnu

  RECOMMENDED FEATURES (should all be yes)
    gzip support                       : yes
    bzip2 support                      : yes
    lzma/xz support                    : yes
    libstdc++ demangle support         : yes
    File textrel check                 : yes
    Symbol versioning                  : yes

  NOT RECOMMENDED FEATURES (should all be no)
    Experimental thread safety         : no

  OTHER FEATURES
    Deterministic archives by default  : false
    Native language support            : yes

  EXTRA TEST FEATURES (used with make check)
    debug branch prediction            : no
    gprof support                      : no
    gcov support                       : no
    run all tests under valgrind       : no
    use rpath in tests                 : no
    test biarch                        : yes

Signed-off-by: Mark Wielaard <mjw@redhat.com>

4 files changed, 57 insertions, 5 deletions

diff --git a/ChangeLog b/ChangeLog
index d45bf673..dc206483 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,10 @@
+2015-05-01  Mark Wielaard  <mjw@redhat.com>
+
+	* configure.ac (debugpred): Use and set use_debugpred_val.
+	(textrelcheck): Explicitly set enable_textrelcheck to yes or no.
+	(symbol-versioning): Likewise for enable_symbol_versioning.
+	AC_MSG_NOTICE overview of enabled/disabled features.
+
 2015-04-23  Max Filippov  <jcmvbkbc@gmail.com>
 
 	* configure.ac: Add --disable-symbol-versioning.
diff --git a/configure.ac b/configure.ac
index be015734..876600d3 100644
--- a/configure.ac
+++ b/configure.ac
@@ -22,7 +22,7 @@ AC_INIT([elfutils],[0.161],[https://bugzilla.redhat.com/],[elfutils])
 AC_CONFIG_AUX_DIR([config])
 AC_CONFIG_FILES([config/Makefile])
 
-AC_COPYRIGHT([Copyright (C) 1996-2014 Red Hat, Inc.])
+AC_COPYRIGHT([Copyright (C) 1996-2015 Red Hat, Inc.])
 AC_PREREQ(2.63)			dnl Minimum Autoconf version required.
 
 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
@@ -170,10 +170,10 @@ AC_ARG_ENABLE([debugpred],
 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 [use_debugpred=$enableval], [use_debugpred=no])
 case $use_debugpred in
- yes) use_debugpred=1 ;;
- *)   use_debugpred=0 ;;
+ yes) use_debugpred_val=1 ;;
+ *)   use_debugpred_val=0 ;;
 esac
-AC_SUBST([DEBUGPRED], $use_debugpred)
+AC_SUBST([DEBUGPRED], $use_debugpred_val)
 
 dnl Enable gprof suport.
 AC_ARG_ENABLE([gprof],
@@ -240,13 +240,16 @@ AC_ARG_ENABLE([textrelcheck],
 AS_HELP_STRING([--disable-textrelcheck],
                [Disable textrelcheck being a fatal error]))
 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
+AS_IF([test "x$enable_textrelcheck" != "xno"],
+      [enable_textrelcheck=yes],[enable_textrelcheck=no])
 
 AC_ARG_ENABLE([symbol-versioning],
 AS_HELP_STRING([--disable-symbol-versioning],
                [Disable symbol versioning in shared objects]))
 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 AS_IF([test "x$enable_symbol_versioning" = "xno"],
-      [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])])
+      [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
+       enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 
 dnl The directories with content.
 
@@ -358,3 +361,39 @@ CC_BIARCH="$CC $utrace_biarch"
 AC_SUBST([CC_BIARCH])
 
 AC_OUTPUT
+
+AC_MSG_NOTICE([
+=====================================================================
+        elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
+=====================================================================
+
+    Prefix                             : ${prefix}
+    Program prefix ("eu-" recommended) : ${program_prefix}
+    Source code location               : ${srcdir}
+    Maintainer mode                    : ${enable_maintainer_mode}
+    libebl modules subdirectory        : ${LIBEBL_SUBDIR}
+    build arch                         : ${ac_cv_build}
+
+  RECOMMENDED FEATURES (should all be yes)
+    gzip support                       : ${with_zlib}
+    bzip2 support                      : ${with_bzlib}
+    lzma/xz support                    : ${with_lzma}
+    libstdc++ demangle support         : ${ac_cv_lib_stdcpp___cxa_demangle}
+    File textrel check                 : ${enable_textrelcheck}
+    Symbol versioning                  : ${enable_symbol_versioning}
+
+  NOT RECOMMENDED FEATURES (should all be no)
+    Experimental thread safety         : ${use_locks}
+
+  OTHER FEATURES
+    Deterministic archives by default  : ${default_ar_deterministic}
+    Native language support            : ${USE_NLS}
+
+  EXTRA TEST FEATURES (used with make check)
+    debug branch prediction            : ${use_debugpred}
+    gprof support                      : ${use_gprof}
+    gcov support                       : ${use_gcov}
+    run all tests under valgrind       : ${use_valgrind}
+    use rpath in tests                 : ${tests_use_rpath}
+    test biarch                        : ${utrace_cv_cc_biarch}
+])
diff --git a/m4/ChangeLog b/m4/ChangeLog
index 163ee734..9ee06d75 100644
--- a/m4/ChangeLog
+++ b/m4/ChangeLog
@@ -1,3 +1,7 @@
+2015-05-01  Mark Wielaard  <mjw@redhat.com>
+
+	* zip.m4: Explicitly set with_ to no, if not yes.
+
 2014-07-14  Mark Wielaard  <mjw@redhat.com>
 
 	* biarch.m4 (utrace_BIARCH): Set biarch-no for cross-compile using
diff --git a/m4/zip.m4 b/m4/zip.m4
index 8e4d545c..ab6fd57e 100644
--- a/m4/zip.m4
+++ b/m4/zip.m4
@@ -14,5 +14,7 @@ fi
 AM_CONDITIONAL([$2], test $with_[$1] = yes)
 if test $with_[$1] = yes; then
   AC_DEFINE(USE_[$2])
+else
+  with_[$1]=no
 fi
 AH_TEMPLATE(USE_[$2], [Support $5 decompression via -l$3.])])